Hi Keith,
Thanks for your attention. As you said, i got a success message for each dll. But still the problem exists.
In my post i had mentioned something about a batch file, i am listing the contents of the file here:
________________________________________________________________________________
:
REM Windows Update FIX
REM Created by Negster22 12-6-05
REM V1.03 1-18-06 Updated to rename catroot2 folder and registered wups2.dll and msxml.dll
:
::Clears out proxy cache, places Windows Update sites in the Trusted Zone, places Windows Update sites in the exception list of IE Popup Blocker
::Starts all dependent services, registers required DLLS, empty the windows updates temporary folder, and deletes BITS pending download queue
:
REM start /w regedit.exe /s Ad-trusted.reg
cd \
color 0e
Rem Clear out proxy cache
proxycfg -d
REG QUERY "HKLM\SOFTWARE\Policies\Microsoft\Windows\CurrentVersion\Internet Settings" /v Security_HKLM_only | find /i "Security_HKLM_Only" | find "1"
GOTO CONTROL%ERRORLEVEL%
:CONTROL0
REM MODIFY GLOBAL MACHINE SETTINGS
color 1f
REG ADD "HKLM\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap\Domains\microsoft.com\update" /V http /t REG_DWORD /D 2 /F
REG ADD "HKLM\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap\Domains\microsoft.com\update" /V https /t REG_DWORD /D 2 /F
REG ADD "HKLM\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap\Domains\microsoft.com\windowsupdate" /V http /t REG_DWORD /D 2 /F
reg add "HKLM\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap\Domains\update.microsoft.com" /v http /t REG_DWORD /D 2 /f
reg add "HKLM\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap\Domains\update.microsoft.com" /v https /t REG_DWORD /D 2 /f
reg add "HKLM\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap\Domains\windowsupdate.com" /v http /t REG_DWORD /D 2 /f
reg add "HKLM\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap\Domains\windowsupdate.microsoft.com" /v http /t REG_DWORD /D 2 /f
reg add "HKLM\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap\Domains\download.microsoft.com" /v http /t REG_DWORD /D 2 /f
:Allow popups from the following Windows Update sites in Internet Explorer
reg add "HKLM\Software\Microsoft\Internet Explorer\New Windows\Allow" /v *.microsoft.com /t REG_BINARY /f
reg add "HKLM\Software\Microsoft\Internet Explorer\New Windows\Allow" /v *.download.microsoft.com /t REG_BINARY /f
reg add "HKLM\Software\Microsoft\Internet Explorer\New Windows\Allow" /v *.windowsupdate.com /t REG_BINARY /f
reg add "HKLM\Software\Microsoft\Internet Explorer\New Windows\Allow" /v *.windowsupdate.microsoft.com /t REG_BINARY /f
GOTO CONTINUE
:CONTROL1
REM MODIFY LOCAL USER SETTINGS
color 5b
:Add Windows Update sites to the Trusted Zone of Internet Explorer (if Security_HKLM_only is not set, use HKCU)
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap\Domains\microsoft.com\update" /V http /t REG_DWORD /D 2 /F
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap\Domains\microsoft.com\update" /V https /t REG_DWORD /D 2 /F
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap\Domains\microsoft.com\windowsupdate" /V http /t REG_DWORD /D 2 /F
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap\Domains\update.microsoft.com" /v http /t REG_DWORD /D 2 /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap\Domains\update.microsoft.com" /v https /t REG_DWORD /D 2 /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap\Domains\windowsupdate.com" /v http /t REG_DWORD /D 2 /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap\Domains\windowsupdate.microsoft.com" /v http /t REG_DWORD /D 2 /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap\Domains\download.microsoft.com" /v http /t REG_DWORD /D 2 /f
:Allow popups from the following Windows Update sites in Internet Explorer
reg add "HKCU\Software\Microsoft\Internet Explorer\New Windows\Allow" /v *.microsoft.com /t REG_BINARY /f
reg add "HKCU\Software\Microsoft\Internet Explorer\New Windows\Allow" /v *.download.microsoft.com /t REG_BINARY /f
reg add "HKCU\Software\Microsoft\Internet Explorer\New Windows\Allow" /v *.windowsupdate.com /t REG_BINARY /f
reg add "HKCU\Software\Microsoft\Internet Explorer\New Windows\Allow" /v *.windowsupdate.microsoft.com /t REG_BINARY /f
:CONTINUE
:Stop the Windows Update and BITS service while applying fixes
Net stop WuAuServ
Net stop BITS
:Register required DLLs
regsvr32 /s wuapi.dll
regsvr32 /s wups.dll
regsvr32 /s wuaueng.dll
regsvr32 /s wuaueng1.dll
regsvr32 /s wucltui.dll
regsvr32 /s wuweb.dll
regsvr32 /s jscript.dll
regsvr32 /s atl.dll
regsvr32 /s softpub.dll
regsvr32 /s msxml3.dll
:Added next two DLLs in v1.03
regsvr32 /s wups2.dll
regsvr32 /s msxml.dll
regsvr32 /s qmgr.dll
regsvr32 /s qmgrprxy.dll
:
::Clear all the pending downloads from BITS & let BITS recreate qmgr0.dat and qmgr1.dat
cd %ALLUSERSPROFILE%\Application Data\Microsoft\Network\Downloader
del *.* /Q
:
: Rename the Catroot2 directory, since it is automatically recreated by Windows
:
net stop cryptsvc
IF EXIST %systemroot%\system32\catroot2 attrib -r -s -h %systemroot%\system32\catroot2
REM Make allowances for the fix having been run more than once. Check if the dir was already renamed in prior run
IF EXIST %systemroot%\system32\oldcatroot2 rmdir /Q /S %systemroot%\system32\oldcatroot2
IF EXIST %systemroot%\system32\catroot2 ren %systemroot%\system32\catroot2 oldcatroot2
:
cd %WINDIR%
::See if temp dir exists from previous execution of script, and delete if it does (XP & 2000)
IF EXIST Sdold rmdir /Q /S Sdold
:Clear old data but save Windows Update temp dir
attrib -r -h -s SoftwareDistribution
ren SoftwareDistribution Sdold
:
:Stop and start the Automatic Update service, so it will recreate the temp folder
Net start WuAuServ
Net stop WuAuServ
:
:Now restore Update History file from backup
attrib -r -h -s SoftwareDistribution
mkdir %WINDIR%\SoftwareDistribution\DataStore
copy %WINDIR%\Sdold\DataStore\DataStore.edb %WINDIR%\SoftwareDistribution\DataStore\
:
:Now restore EventsLog file from backup
COPY /y %WINDIR%\Sdold\ReportingEvents.log %WINDIR%\SoftwareDistribution\
:
:Restart automatic updates service. Start all other dependent services and set to automatic startup. Set the following services to autostart
:Background Intelligent Transfer Service (BITS), Automatic Updates (WuAuServ), Event Log (EventLog), Cryptographic Services (CryptSvc), :Remote Procedure Call (RpcSs)
:
Net start WuAuServ
sc config WuAuServ start= auto
::Set to automatic
::Start Background Intelligent Transfer Service
Net start BITS
::Set BITS to manual
sc config BITS start= demand
::Start Event Log Service
Net start EventLog
sc config EventLog start= auto
::Start Cryptographic Services
Net start CryptSvc
sc config CryptSvc start= auto
::Turn on Remote Procedure Call Service
Net start RpcSs
sc config RpcSs start= auto
:EXIT
________________________________________________________________________________
________
I noticed that those DLLs you mentioned were in the batch file, still i did as you said, i thought maybe doing only the juicy part and not the whole lot could make a difference.....but no. The updates still elude me.